home *** CD-ROM | disk | FTP | other *** search
/ Collection of Tools & Utilities / Collection of Tools and Utilities.iso / clipper / nfsrc21.zip / ACCTMNTH.PRG < prev    next >
Text File  |  1992-09-28  |  5KB  |  141 lines
  1. /*
  2.  * File......: ACCTMNTH.PRG
  3.  * Author....: Jo W. French dba Practical Computing
  4.  * CIS ID....: 74731,1751
  5.  * Date......: $Date:   28 Sep 1992 00:24:54  $
  6.  * Revision..: $Revision:   1.3  $
  7.  * Log file..: $Logfile:   C:/nanfor/src/acctmnth.prv  $
  8.  * 
  9.  * The functions contained herein are the original work of Jo W. French
  10.  * and are placed in the public domain.
  11.  *
  12.  * Modification history:
  13.  * ---------------------
  14.  *
  15.  * $Log:   C:/nanfor/src/acctmnth.prv  $
  16.  * 
  17.  *    Rev 1.3   28 Sep 1992 00:24:54   GLENN
  18.  * Jo French clean up.
  19.  * 
  20.  *    Rev 1.2   15 Aug 1991 23:02:30   GLENN
  21.  * Forest Belt proofread/edited/cleaned up doc
  22.  * 
  23.  *    Rev 1.1   14 Jun 1991 19:50:42   GLENN
  24.  * Minor edit to file header
  25.  * 
  26.  *    Rev 1.0   01 Apr 1991 01:00:24   GLENN
  27.  * Nanforum Toolkit
  28.  *
  29.  */
  30.  
  31. /*  $DOC$
  32.  *  $FUNCNAME$
  33.  *     FT_ACCTMONTH()
  34.  *  $CATEGORY$
  35.  *     Date/Time
  36.  *  $ONELINER$
  37.  *     Return accounting month data
  38.  *  $SYNTAX$
  39.  *     FT_ACCTMONTH( [ <dGivenDate> ], [ <nMonthNum> ] ) -> aDateInfo
  40.  *  $ARGUMENTS$
  41.  *     <dGivenDate> is any valid date in any date format.  Defaults
  42.  *     to current system date if not supplied.
  43.  *
  44.  *     <nMonthNum> is a number from 1 to 12 signifying a month.
  45.  *     Defaults to current month if not supplied.
  46.  *  $RETURNS$
  47.  *     A three element array containing the following data:
  48.  *
  49.  *        aDateInfo[1] - The year and month as a character string "YYYYMM"
  50.  *        aDateInfo[2] - The beginning date of the accounting month
  51.  *        aDateInfo[3] - The ending date of the accounting month
  52.  *  $DESCRIPTION$
  53.  *     FT_ACCTMONTH() creates an array containing data about the
  54.  *     accounting month containing the given date.
  55.  *
  56.  *     An accounting period has the following characteristics:
  57.  *
  58.  *     If the first week of the period contains 4 or more 'work'
  59.  *     days, it is included in the period; otherwise, the first
  60.  *     week was included in the prior period.
  61.  *
  62.  *     If the last week of the period contains 4 or more 'work'
  63.  *     days it is included in the period; otherwise, the last week
  64.  *     is included in the next period.  This results in 13 week
  65.  *     'quarters' and 4 or 5 week 'months'.  Every 5 or 6 years, a
  66.  *     'quarter' will contain 14 weeks and the year will contain 53
  67.  *     weeks.
  68.  *  $EXAMPLES$
  69.  *     // get info about accounting month containing 9/15/90
  70.  *     aDateInfo := FT_ACCTMONTH( Ctod("09/15/90") )
  71.  *     ? aDateInfo[1]   //  199009       (9th month)
  72.  *     ? aDateInfo[2]   //  09/02/90     beginning of month 9
  73.  *     ? aDateInfo[3]   //  09/29/90     end of month 9
  74.  *
  75.  *     // get info about accounting month 5 in year containing 9/15/90
  76.  *     aDateInfo := FT_ACCTMONTH( Ctod("09/15/90"), 5 )
  77.  *     ? aDateInfo[1]   //  199005
  78.  *     ? aDateInfo[2]   //  04/29/89   beginning of month 5
  79.  *     ? aDateInfo[3]   //  06/02/90   end of month 5
  80.  *  $SEEALSO$
  81.  *     FT_DATECNFG() FT_ACCTWEEK() FT_ACCTQTR() FT_ACCTYEAR()
  82.  *  $END$
  83. */
  84.  
  85. FUNCTION FT_ACCTMONTH(dGivenDate,nMonthNum)
  86.   LOCAL nYTemp, nMTemp, lIsMonth, aRetVal
  87.  
  88.   IF ! ( VALTYPE(dGivenDate) $ 'ND' )
  89.     dGivenDate := DATE()
  90.   ELSEIF VALTYPE(dGivenDate) == 'N'
  91.     nMonthNum := dGivenDate
  92.     dGivenDate := DATE()
  93.   ENDIF
  94.  
  95.   aRetVal := FT_MONTH(dGivenDate)
  96.   nYTemp := VAL(SUBSTR(aRetVal[1],1,4))
  97.   nMTemp := VAL(SUBSTR(aRetVal[1],5,2))
  98.   aRetVal[2] := FT_ACCTADJ(aRetVal[2])
  99.   aRetVal[3] := FT_ACCTADJ(aRetVal[3], .T. )
  100.  
  101.   IF dGivenDate < aRetVal[2]
  102.     dGivenDate := FT_MADD(dGivenDate, -1)
  103.     aRetVal    := FT_MONTH(dGivenDate)
  104.     nMTemp     -= 1
  105.     IF nMTemp  == 0
  106.        nYTemp -= 1
  107.        nMTemp := 12
  108.     ENDIF
  109.     aRetVal[2] := FT_ACCTADJ(aRetVal[2])
  110.     aRetVal[3] := FT_ACCTADJ(aRetVal[3], .T. )
  111.  
  112.   ELSEIF dGivenDate > aRetVal[3]
  113.  
  114.     dGivenDate := FT_MADD(dGivenDate, 1)
  115.     aRetVal    := FT_MONTH(dGivenDate)
  116.     nMTemp     += 1
  117.     IF nMTemp == 13
  118.        nYTemp += 1
  119.        nMTemp := 1
  120.     ENDIF
  121.     aRetVal[2] := FT_ACCTADJ(aRetVal[2])
  122.     aRetVal[3] := FT_ACCTADJ(aRetVal[3], .T. )
  123.  
  124.   ENDIF
  125.  
  126.   lIsMonth := ( VALTYPE(nMonthNum) == 'N' )
  127.   IF lIsMonth
  128.     IF( nMonthNum < 1 .OR. nMonthNum > 12 , nMonthNum := 12, )
  129.     aRetVal    := FT_MONTH(dGivenDate, nMonthNum)
  130.     nYTemp     := VAL(SUBSTR(aRetVal[1],1,4))
  131.     nMTemp     := VAL(SUBSTR(aRetVal[1],5,2))
  132.     aRetVal[2] := FT_ACCTADJ(aRetVal[2])
  133.     aRetVal[3] := FT_ACCTADJ(aRetVal[3], .T. )
  134.   ENDIF
  135.  
  136.   aRetVal[1] := STR(nYTemp,4) + PADL(LTRIM(STR(nMTemp,2)), 2, '0')
  137.  
  138. RETURN aRetVal
  139.  
  140.  
  141.